<xsl:choose> |
The <xsl:choose> element is XSLT's version of the switch or case statement found in many procedural programming languages.
Category
Instruction
Required Attributes
None.
Optional Attributes
None.
Content
Contains one or more <xsl:when> elements and might contain a single <xsl:otherwise> element. Any <xsl:otherwise> elements must be the last element inside <xsl:choose>.
Appears in
<xsl:choose> appears inside a template.
Defined in
XSLT section 9.2, Conditional Processing with xsl:choose.
Example
Here's an example that uses <xsl:choose> to select the background color for the rows of an HTML table. We cycle among four different values, using <xsl:choose> to determine the value of the bgcolor attribute in the generated HTML document. Here's the XML document we'll use:
    <?xml version="1.0"?>
    <list xml:lang="en">
      <title>Albums I've bought recently:</title>
      <listitem>The Sacred Art of Dub</listitem>
      <listitem>Only the Poor Man Feel It</listitem>
      <listitem>Excitable Boy</listitem>
      <listitem xml:lang="sw">Aki Special</listitem>
      <listitem xml:lang="en-gb">Combat Rock</listitem>
      <listitem xml:lang="zu">Talking Timbuktu</listitem>
      <listitem xml:lang="jz">The Birth of the Cool</listitem>
    </list>
And here's our stylesheet:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="html"/>

      <xsl:template match="/">
        <html>
          <head>
            <title>
              <xsl:value-of select="list/title"/>
            </title>
          </head>
          <body>
            <h1><xsl:value-of select="list/title"/></h1>
            <table border="1">
              <xsl:for-each select="list/listitem">
                <tr>
                  <td>
                    <xsl:attribute name="bgcolor">
                      <xsl:choose>
                        <xsl:when test="position() mod 4 = 0">
                          <xsl:text>papayawhip</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 1">
                          <xsl:text>mintcream</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 2">
                          <xsl:text>lavender</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:text>whitesmoke</xsl:text>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    <xsl:value-of select="."/>
                  </td>
                </tr>
              </xsl:for-each>
            </table>
          </body>
        </html>
      </xsl:template>

    </xsl:stylesheet>
We use <xsl:choose> to determine the background color of each generated <td> element. Here's the generated HTML document, which cycles through the various background colors:
    <html>
    <head>
    <META http-equiv="Content-Type" content="text/html; charset=UTF-8">
    <title>Albums I've bought recently:</title>
    </head>
    <body>
    <h1>Albums I've bought recently:</h1>
    <table border="1">
    <tr>
    <td bgcolor="mintcream">The Sacred Art of Dub</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Only the Poor Man Feel It</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">Excitable Boy</td>
    </tr>
    <tr>
    <td bgcolor="papayawhip">Aki Special</td>
    </tr>
    <tr>
    <td bgcolor="mintcream">Combat Rock</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Talking Timbuktu</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">The Birth of the Cool</td>
    </tr>
    </table>
    </body>
    </html>
When rendered, our HTML document looks like Figure A-5.

Document cycling among different background colors