CFLOGIN |
Description A container for user login and authentication code. ColdFusion runs the code in this tag if a user is not already logged in. You put code in the tag that authenticates the user and identifies the user with a set of roles. Used with cfloginuser tag.
Category Security tags
Syntax
    <cflogin
       idletimeout = "value"
       applicationToken = "token"
       cookieDomain = "domain"
       ...
       <cfloginuser
          name = "name"
          password = "password-string"
          roles = "roles">
       ...>
    </cflogin>
See also cfloginuser, cflogout, GetAuthUser, IsUserInRole, Chapter 16, "Securing Applications" in ColdFusion MX Developer's Guide
History ColdFusion MX 6.1: Changed behavior: the cflogin variable exists when ColdFusion receives a request with NTLM or Digest (CFHTTP Negotiated header) authentication information. ColdFusion MX: Added this tag.
Usage The body of this tag executes only if there is no logged-in user. When using application-based security, you put code in the body of the cflogin tag to check the user-provided ID and password against a data source, LDAP directory, or other repository of login identification. The body must include a cfloginuser tag to establish the authenticated user's identity in ColdFusion.

You control the data source and are responsible for coding the SQL within the cflogin tag, and you must make sure that the associated database has user, password, and role information.

The cflogin tag has a built-in cflogin structure that contains two variables, cflogin.name and cflogin.password, if the page is executing in response to any of the following:

- Submission of a form that contains input fields with the names j_username and j_password.
- A request that uses CFHTTP Basic authentication, and therefore includes an Authorization header with the username and password.
- A request that uses NTLM or Digest authentication. In this case, the username and password are hashed using a one-way algorithm in the Authorization header; ColdFusion gets the username from the web server and sets the cflogin.password value to the empty string.

You can use these values in the cflogin tag body to authenticate the user, and, in the cfloginuser tag, to log the user in. The structure is only available in the cflogin tag body.

Example The following example shows a simple authentication. This code is typically in the Application.cfc onRequestStart method or in the application.cfm page.
    <cflogin>
       <cfif NOT IsDefined("cflogin")>
          <cfinclude template="loginform.cfm">
          <cfabort>
       <cfelse>
          <cfif cflogin.name eq "admin">
             <cfset roles = "user,admin">
          <cfelse>
                <cfset roles = "user">
          </cfif>
          <cfloginuser name = "#cflogin.name#" password = "#cflogin.password#"
             roles = "#roles#" />
       </cfif>
    </cflogin>
The following view-only example checks the user ID and password against a data source:
    <cfquery name="qSecurity"
       datasource="UserRolesDb">
       select Roles FROM SecurityRoles
       where username=<cfqueryparam value="#cflogin.name#"
          CFSQLTYPE="CF_SQL_VARCHAR"
       and password=<cfqueryparam value="#cflogin.password#"
          CFSQLTYPE="CF_SQL_VARCHAR"
    </cfquery>

    <cfif qSecurity.recordcount gt 0>
    <cfloginuser name = "#cflogin.name#"
    password = "#cflogin.password#"
    roles = "#trim(qSecurity.Roles)#" >
    </cfif>

IDLETIMEOUT |
| Optional
Default value: "1800" Time interval, in seconds, after which ColdFusion logs off the user.

APPLICATIONTOKEN |
| Optional
Default value: "The current application name" Unique application identifier. Limits the login validity to one application, as specified by the cfapplication tag or the Application.cfc file.

COOKIEDOMAIN |
| Optional
Domain of the cookie that is used to mark a user as logged in. Use this attribute to enable a user login cookie to work with multiple clustered servers in the same domain.